module View.Payment.Add
  ( view
  , In(..)
  ) where

import           Control.Monad          (join)
import           Control.Monad.IO.Class (liftIO)
import qualified Data.Text              as T
import qualified Data.Time.Clock        as Time
import           Reflex.Dom             (Dynamic, Event, MonadWidget)
import qualified Reflex.Dom             as R

import           Common.Model           (Category (..), CreatePaymentForm (..),
                                         Frequency (..), Payment (..),
                                         PaymentCategory (..),
                                         SavedPayment (..))
import qualified Common.Msg             as Msg
import qualified Common.Util.Time       as TimeUtil
import qualified Component.Modal        as Modal
import qualified Util.Ajax              as Ajax
import qualified Util.Reflex            as ReflexUtil
import qualified View.Payment.Form      as Form

data In t = In
  { _in_categories        :: [Category]
  , _in_paymentCategories :: Dynamic t [PaymentCategory]
  , _in_frequency         :: Dynamic t Frequency
  }

view :: forall t m. MonadWidget t m => In t -> Modal.Content t m SavedPayment
view input cancel = do

  currentDay <- liftIO $ Time.getCurrentTime >>= TimeUtil.timeToDay

  formOutput <- R.dyn $ do
    paymentCategories <- _in_paymentCategories input
    frequency <- _in_frequency input
    return $ Form.view $ Form.In
      { Form._in_cancel = cancel
      , Form._in_headerLabel = Msg.get Msg.Payment_Add
      , Form._in_categories = _in_categories input
      , Form._in_paymentCategories = paymentCategories
      , Form._in_name = ""
      , Form._in_cost = ""
      , Form._in_date = currentDay
      , Form._in_category = -1
      , Form._in_frequency = frequency
      , Form._in_mkPayload = CreatePaymentForm
      , Form._in_ajax = Ajax.post
      }

  hide <- ReflexUtil.flatten (Form._output_hide <$> formOutput)
  addPayment <- ReflexUtil.flatten (Form._output_addPayment <$> formOutput)

  return (hide, addPayment)