module View.Payment.Delete
  ( view
  , DeleteIn(..)
  , DeleteOut(..)
  ) where

import           Data.Text            (Text)
import qualified Data.Text            as T
import           Reflex.Dom           (Dynamic, Event, MonadWidget)
import qualified Reflex.Dom           as R

import           Common.Model.Payment (PaymentId)
import qualified Common.Msg           as Msg
import           Component            (ButtonIn (..), ButtonOut (..))
import qualified Component            as Component
import qualified Util.Ajax            as Ajax
import qualified Util.Either          as EitherUtil
import qualified Util.WaitFor         as WaitFor

data DeleteIn t = DeleteIn
  { _deleteIn_id :: Dynamic t PaymentId
  }

data DeleteOut t = DeleteOut
  { _deleteOut_cancel   :: Event t ()
  , _deleteOut_validate :: Event t PaymentId
  }

view :: forall t m. MonadWidget t m => (DeleteIn t) -> m (DeleteOut t)
view deleteIn =
  R.divClass "delete" $ do
    R.divClass "deleteHeader" $ R.text $ Msg.get Msg.Payment_DeleteConfirm

    R.divClass "deleteContent" $ do

      (deletedPayment, cancel) <- R.divClass "buttons" $ do

        cancel <- Component._buttonOut_clic <$> (Component.button $
          (Component.defaultButtonIn (R.text $ Msg.get Msg.Dialog_Undo))
            { _buttonIn_class = R.constDyn "undo" })

        rec
          confirm <- Component._buttonOut_clic <$> (Component.button $
            (Component.defaultButtonIn (R.text $ Msg.get Msg.Dialog_Confirm))
              { _buttonIn_class = R.constDyn "confirm"
              , _buttonIn_submit = True
              , _buttonIn_waiting = waiting
              })

          let url = flip fmap (_deleteIn_id deleteIn) (\id ->
                  T.concat ["/payment/", T.pack . show $ id]
                )

          (result, waiting) <- WaitFor.waitFor
            (Ajax.delete url)
            confirm

        return (R.fmapMaybe EitherUtil.eitherToMaybe result, cancel)

      return DeleteOut
        { _deleteOut_cancel = cancel
        , _deleteOut_validate = R.tag (R.current $ _deleteIn_id deleteIn) deletedPayment
        }