module View.Payment.Header
  ( widget
  , HeaderIn(..)
  , HeaderOut(..)
  ) where

import           Control.Monad          (forM_)
import           Control.Monad.IO.Class (liftIO)
import qualified Data.List              as L hiding (groupBy)
import qualified Data.Map               as M
import           Data.Maybe             (fromMaybe)
import           Data.Text              (Text)
import qualified Data.Text              as T
import           Data.Time              (NominalDiffTime)
import qualified Data.Time              as Time
import           Prelude                hiding (init)
import           Reflex.Dom             (Dynamic, Event, MonadWidget, Reflex)
import qualified Reflex.Dom             as R

import           Common.Model           (Category, CreatedPayment (..),
                                         Currency, ExceedingPayer (..),
                                         Frequency (..), Income (..), Init (..),
                                         Payment (..), PaymentCategory,
                                         User (..))
import qualified Common.Model           as CM
import qualified Common.Msg             as Msg
import qualified Common.View.Format     as Format

import           Component              (ButtonIn (..), ButtonOut (..),
                                         InputIn (..), InputOut (..),
                                         ModalIn (..), ModalOut (..),
                                         SelectIn (..), SelectOut (..))
import qualified Component              as Component
import qualified Util.List              as L
import           View.Payment.Add       (AddIn (..), AddOut (..))
import qualified View.Payment.Add       as Add

data HeaderIn t = HeaderIn
  { _headerIn_init              :: Init
  , _headerIn_payments          :: Dynamic t [Payment]
  , _headerIn_searchPayments    :: Dynamic t [Payment]
  , _headerIn_paymentCategories :: Dynamic t [PaymentCategory]
  }

data HeaderOut t = HeaderOut
  { _headerOut_searchName      :: Dynamic t Text
  , _headerOut_searchFrequency :: Dynamic t Frequency
  , _headerOut_addPayment      :: Event t CreatedPayment
  }

widget :: forall t m. MonadWidget t m => HeaderIn t -> m (HeaderOut t)
widget headerIn =
  R.divClass "header" $ do
    addPayment <- payerAndAdd incomes payments users categories paymentCategories currency
    let resetSearchName = fmap (const ()) $ addPayment
    (searchName, searchFrequency)  <- searchLine resetSearchName

    infos (_headerIn_searchPayments headerIn) users currency

    return $ HeaderOut
      { _headerOut_searchName = searchName
      , _headerOut_searchFrequency = searchFrequency
      , _headerOut_addPayment = addPayment
      }
  where
    init = _headerIn_init headerIn
    incomes = _init_incomes init
    initPayments = _init_payments init
    payments = _headerIn_payments headerIn
    users = _init_users init
    categories = _init_categories init
    currency = _init_currency init
    paymentCategories = _headerIn_paymentCategories headerIn

payerAndAdd
  :: forall t m. MonadWidget t m
  => [Income]
  -> Dynamic t [Payment]
  -> [User]
  -> [Category]
  -> Dynamic t [PaymentCategory]
  -> Currency
  -> m (Event t CreatedPayment)
payerAndAdd incomes payments users categories paymentCategories currency = do
  time <- liftIO Time.getCurrentTime
  R.divClass "payerAndAdd" $ do

    let exceedingPayers =
          R.ffor payments $ \ps ->
            CM.getExceedingPayers time users incomes $
              filter ((==) Punctual . _payment_frequency) ps

    R.divClass "exceedingPayers" $
      R.simpleList exceedingPayers $ \exceedingPayer ->
        R.elClass "span" "exceedingPayer" $ do
          R.elClass "span" "userName" $
            R.dynText . R.ffor exceedingPayer $ \ep ->
              fromMaybe "" . fmap _user_name $ CM.findUser (_exceedingPayer_userId ep) users
          R.elClass "span" "amount" $ do
            R.text "+ "
            R.dynText . R.ffor exceedingPayer $ \ep ->
              Format.price currency $ _exceedingPayer_amount ep

    addPaymentClic <- _buttonOut_clic <$> (Component.button $ ButtonIn
      { _buttonIn_class = R.constDyn "addPayment"
      , _buttonIn_content = R.text $ Msg.get Msg.Payment_Add
      , _buttonIn_waiting = R.never
      , _buttonIn_tabIndex = Nothing
      , _buttonIn_submit = False
      })

    rec
      modalOut <- Component.modal $ ModalIn
        { _modalIn_show    = addPaymentClic
        , _modalIn_hide = R.leftmost $
            [ _addOut_cancel addOut
            , fmap (const ()) . _addOut_addPayment $ addOut
            ]
        , _modalIn_content = Add.view $ AddIn
            { _addIn_categories = categories
            , _addIn_paymentCategories = paymentCategories
            , _addIn_cancel = _modalOut_hide modalOut
            }
        }
      let addOut = _modalOut_content modalOut
    return (_addOut_addPayment addOut)

searchLine
  :: forall t m. MonadWidget t m
  => Event t ()
  -> m (Dynamic t Text, Dynamic t Frequency)
searchLine reset = do
  R.divClass "searchLine" $ do
    searchName <- _inputOut_raw <$> (Component.input
      ( Component.defaultInputIn { _inputIn_label = Msg.get Msg.Search_Name })
      (const "" <$> reset)
      R.never)

    let frequencies = M.fromList
          [ (Punctual, Msg.get Msg.Payment_PunctualMale)
          , (Monthly, Msg.get Msg.Payment_MonthlyMale)
          ]

    searchFrequency <- _selectOut_raw <$> (Component.select $
      SelectIn
        { _selectIn_label        = ""
        , _selectIn_initialValue = Punctual
        , _selectIn_value        = R.never
        , _selectIn_values       = R.constDyn frequencies
        , _selectIn_reset        = R.never
        , _selectIn_isValid      = const True
        , _selectIn_validate     = R.never
        })

    return (searchName, searchFrequency)

infos
  :: forall t m. MonadWidget t m
  => Dynamic t [Payment]
  -> [User]
  -> Currency -> m ()
infos payments users currency =
  R.divClass "infos" $ do

    R.elClass "span" "total" $ do
      R.dynText $ do
        ps <- payments
        let paymentCount = length ps
            total = sum . map _payment_cost $ ps
        pure . Msg.get $ Msg.Payment_Worth
          (T.intercalate " "
            [ (Format.number paymentCount)
            , if paymentCount > 1
                then Msg.get Msg.Payment_Many
                else Msg.get Msg.Payment_One
            ])
          (Format.price currency total)

    R.elClass "span" "partition" . R.dynText $ do
      ps <- payments
      let totalByUser =
            L.sortBy (\(_, t1) (_, t2) -> compare t2 t1)
              . map (\(u, xs) -> (u, sum . map snd $ xs))
              . L.groupBy fst
              . map (\p -> (_payment_user p, _payment_cost p))
              $ ps
      pure . T.intercalate ", " . flip map totalByUser $ \(userId, userTotal) ->
        Msg.get $ Msg.Payment_By
          (fromMaybe "" . fmap _user_name $ CM.findUser userId users)
          (Format.price currency userTotal)