module View.Payment.Payment
  ( init
  , view
  , In(..)
  ) where

import           Data.Text           (Text)
import qualified Data.Text           as T
import           Data.Time.Clock     (NominalDiffTime)
import           Prelude             hiding (init)
import           Reflex.Dom          (Dynamic, Event, MonadWidget, Reflex)
import qualified Reflex.Dom          as R

import           Common.Model        (Currency, Frequency, Income (..),
                                      Payment (..), PaymentCategory (..),
                                      PaymentId, SavedPayment (..), User,
                                      UserId)
import qualified Common.Util.Text    as T

import           Loadable            (Loadable (..))
import qualified Loadable
import qualified Util.Ajax           as AjaxUtil
import qualified View.Payment.Header as Header
import           View.Payment.Init   (Init (..))
import qualified View.Payment.Pages  as Pages
import qualified View.Payment.Table  as Table

init :: forall t m. MonadWidget t m => m (Dynamic t (Loadable Init))
init = do
  users <- AjaxUtil.getNow "api/users"
  payments <- AjaxUtil.getNow "api/payments"
  incomes <- AjaxUtil.getNow "api/deprecated/incomes"
  categories <- AjaxUtil.getNow "api/categories"
  paymentCategories <- AjaxUtil.getNow "api/paymentCategories"
  return $ do
    us <- users
    ps <- payments
    is <- incomes
    cs <- categories
    pcs <- paymentCategories
    return $ Init <$> us <*> ps <*> is <*> cs <*> pcs


data In t = In
  { _in_currentUser :: UserId
  , _in_currency    :: Currency
  , _in_init        :: Dynamic t (Loadable Init)
  }

view :: forall t m. MonadWidget t m => In t -> m ()
view input = do
  R.dyn . R.ffor (_in_init input) . Loadable.view $ \init ->

    R.elClass "main" "payment" $ do
      rec
        let addPayment = R.leftmost
              [ Header._out_addPayment header
              , Table._out_addPayment table
              ]

            paymentsPerPage = 7

        payments <- reducePayments
          (_init_payments init)
          (_savedPayment_payment <$> addPayment)
          (_savedPayment_payment <$> Table._out_editPayment table)
          (Table._out_deletePayment table)

        paymentCategories <- reducePaymentCategories
          (_init_paymentCategories init)
          payments
          (_savedPayment_paymentCategory <$> addPayment)
          (_savedPayment_paymentCategory <$> Table._out_editPayment table)
          (Table._out_deletePayment table)

        (searchNameEvent, searchName) <-
          debounceSearchName (Header._out_searchName header)

        let searchPayments =
              getSearchPayments searchName (Header._out_searchFrequency header) payments

        header <- Header.view $ Header.In
          { Header._in_init = init
          , Header._in_currency = _in_currency input
          , Header._in_payments = payments
          , Header._in_searchPayments = searchPayments
          , Header._in_paymentCategories = paymentCategories
          }

        table <- Table.view $ Table.In
          { Table._in_init = init
          , Table._in_currency = _in_currency input
          , Table._in_currentUser = _in_currentUser input
          , Table._in_currentPage = Pages._out_currentPage pages
          , Table._in_payments = searchPayments
          , Table._in_perPage = paymentsPerPage
          , Table._in_paymentCategories = paymentCategories
          }

        pages <- Pages.view $ Pages.In
          { Pages._in_total = length <$> searchPayments
          , Pages._in_perPage = paymentsPerPage
          , Pages._in_reset = R.leftmost $
              [ () <$ searchNameEvent
              , () <$ Header._out_addPayment header
              ]
          }

      pure ()

  return ()

debounceSearchName
  :: forall t m. MonadWidget t m
  => Dynamic t Text
  -> m (Event t Text, Dynamic t Text)
debounceSearchName searchName = do
  event <- R.debounce (0.5 :: NominalDiffTime) (R.updated searchName)
  dynamic <- R.holdDyn "" event
  return (event, dynamic)

reducePayments
  :: forall t m. MonadWidget t m
  => [Payment]
  -> Event t Payment -- add payment
  -> Event t Payment -- edit payment
  -> Event t Payment -- delete payment
  -> m (Dynamic t [Payment])
reducePayments initPayments addPayment editPayment deletePayment =
  R.foldDyn id initPayments $ R.leftmost
    [ (:) <$> addPayment
    , R.ffor editPayment (\p -> (p:) . filter ((/= (_payment_id p)) . _payment_id))
    , R.ffor deletePayment (\p -> filter ((/= (_payment_id p)) . _payment_id))
    ]

reducePaymentCategories
  :: forall t m. MonadWidget t m
  => [PaymentCategory]
  -> Dynamic t [Payment]      -- payments
  -> Event t PaymentCategory  -- add payment category
  -> Event t PaymentCategory  -- edit payment category
  -> Event t Payment          -- delete payment
  -> m (Dynamic t [PaymentCategory])
reducePaymentCategories
  initPaymentCategories
  payments
  addPaymentCategory
  editPaymentCategory
  deletePayment
    =
  R.foldDyn id initPaymentCategories $ R.leftmost
    [ (:) <$> addPaymentCategory
    , R.ffor editPaymentCategory (\pc -> (pc:) . filter ((/= (_paymentCategory_name pc)) . _paymentCategory_name))
    , R.ffor deletePaymentName (\name -> filter ((/=) (T.toLower name) . _paymentCategory_name))
    ]
  where
    deletePaymentName =
      R.attachWithMaybe
        (\ps p ->
          if any (\p2 -> _payment_id p2 /= _payment_id p && lowerName p2 == lowerName p) ps then
            Nothing
          else
            Just (_payment_name p))
        (R.current payments)
        deletePayment
    lowerName = T.toLower . _payment_name

getSearchPayments
  :: forall t. Reflex t
  => Dynamic t Text
  -> Dynamic t Frequency
  -> Dynamic t [Payment]
  -> Dynamic t [Payment]
getSearchPayments name frequency payments = do
  n <- name
  f <- frequency
  ps <- payments
  pure $ flip filter ps (\p ->
    (  (T.search n (_payment_name p) || T.search n (T.pack . show . _payment_cost $ p))
    && (_payment_frequency p == f)
    ))