module Controller.Payment
  ( list
  , create
  , editOwn
  , deleteOwn
  ) where

import           Control.Monad.IO.Class      (liftIO)
import qualified Network.HTTP.Types.Status   as Status
import           Web.Scotty

import           Common.Model                (CreatePayment (..),
                                              EditPayment (..), PaymentId,
                                              User (..))

import qualified Json
import qualified Model.Query                 as Query
import qualified Persistence.Payment         as PaymentPersistence
import qualified Persistence.PaymentCategory as PaymentCategoryPersistence
import qualified Secure

list :: ActionM ()
list =
  Secure.loggedAction (\_ ->
    (liftIO . Query.run $ PaymentPersistence.listActive) >>= json
  )

create :: CreatePayment -> ActionM ()
create (CreatePayment name cost date category frequency) =
  Secure.loggedAction (\user ->
    (liftIO . Query.run $ do
      PaymentCategoryPersistence.save name category
      PaymentPersistence.create (_user_id user) name cost date frequency
    ) >>= Json.jsonId
  )

editOwn :: EditPayment -> ActionM ()
editOwn (EditPayment paymentId name cost date category frequency) =
  Secure.loggedAction (\user -> do
    updated <- liftIO . Query.run $ do
      edited <- PaymentPersistence.editOwn (_user_id user) paymentId name cost date frequency
      _ <- if edited
        then PaymentCategoryPersistence.save name category >> return ()
        else return ()
      return edited
    if updated
      then status Status.ok200
      else status Status.badRequest400
  )

deleteOwn :: PaymentId -> ActionM ()
deleteOwn paymentId =
  Secure.loggedAction (\user -> do
    deleted <- liftIO . Query.run $ PaymentPersistence.deleteOwn (_user_id user) paymentId
    if deleted
      then status Status.ok200
      else status Status.badRequest400
  )