module Update.LoggedView
  ( LoggedAction(..)
  , updateLoggedView
  ) where

import Date
import Dict

import Model exposing (Model)
import Model.User exposing (UserId)
import Model.Payment exposing (..)
import Model.Payers exposing (..)
import Model.View.LoggedView exposing (..)
import Model.View.Payment.Add exposing (..)

import Update.LoggedView.Add exposing (..)
import Update.LoggedView.Monthly as UM

type LoggedAction =
  UpdateAdd AddPaymentAction
  | UpdatePayments Payments
  | AddPayment UserId String Int Payments
  | AddMonthlyPayment PaymentId String Int
  | ToggleEdit PaymentId
  | DeletePayment UserId Int Payments
  | UpdatePage Int Payments
  | UpdateMonthly UM.MonthlyAction

updateLoggedView : Model -> LoggedAction -> LoggedView -> LoggedView
updateLoggedView model action loggedView =
  case action of
    UpdateAdd addPaymentAction ->
      { loggedView | add <- updateAddPayment addPaymentAction loggedView.add }
    UpdatePayments payments ->
      { loggedView | payments <- payments }
    AddPayment userId name cost payments ->
      { loggedView
      | payments <- payments
      , currentPage <- 1
      , add <- initAddPayment Punctual
      , payers <- updatePayers loggedView.payers userId cost
      , paymentsCount <- loggedView.paymentsCount + 1
      }
    AddMonthlyPayment id name cost ->
      { loggedView
      | add <- initAddPayment Monthly
      , monthly <-
          let payment = Payment id (Date.fromTime model.currentTime) name cost loggedView.me
          in  UM.updateMonthly (UM.AddPayment payment) loggedView.monthly
      }
    ToggleEdit id ->
      { loggedView | paymentEdition <- if loggedView.paymentEdition == Just id then Nothing else Just id }
    DeletePayment userId cost payments ->
      { loggedView
      | payments <- payments
      , payers <- updatePayers loggedView.payers userId -cost
      , paymentsCount <- loggedView.paymentsCount - 1
      }
    UpdatePage page payments ->
      { loggedView
      | currentPage <- page
      , payments <- payments
      }
    UpdateMonthly monthlyAction ->
      { loggedView | monthly <- UM.updateMonthly monthlyAction loggedView.monthly }