module Update.Payment
  ( PaymentAction(..)
  , updatePayment
  ) where

import Date
import Dict

import Model exposing (Model)
import Model.User exposing (UserId)
import Model.Payment exposing (..)
import Model.Payers exposing (..)
import Model.View.PaymentView exposing (..)
import Model.View.Payment.Add exposing (..)

import Update.Payment.Add exposing (..)

type PaymentAction =
  UpdateAdd AddPaymentAction
  | UpdatePayments Payments
  | AddPayment UserId Int Payments
  | ToggleEdit PaymentId
  | Remove UserId Int Payments
  | UpdatePage Int Payments

updatePayment : Model -> PaymentAction -> PaymentView -> PaymentView
updatePayment model action paymentView =
  case action of
    UpdateAdd addPaymentAction ->
      { paymentView | add <- updateAddPayment addPaymentAction paymentView.add }
    UpdatePayments payments ->
      { paymentView | payments <- payments }
    AddPayment userId cost payments ->
      { paymentView
      | payments <- payments
      , currentPage <- 1
      , add <- initAddPayment
      , payers <- updatePayers paymentView.payers userId cost
      , paymentsCount <- paymentView.paymentsCount + 1
      }
    ToggleEdit id ->
      { paymentView | edition <- if paymentView.edition == Just id then Nothing else Just id }
    Remove userId cost payments ->
      { paymentView
      | payments <- payments
      , payers <- updatePayers paymentView.payers userId -cost
      , paymentsCount <- paymentView.paymentsCount - 1
      }
    UpdatePage page payments ->
      { paymentView
      | currentPage <- page
      , payments <- payments
      }