module View.Payments.Table
  ( paymentsTable
  ) where

import Html exposing (..)
import Html.Attributes exposing (..)
import Html.Events exposing (..)
import Dict exposing (..)

import Date
import Date exposing (Date)

import String exposing (append)

import Model exposing (Model)
import Model.Payment exposing (..)
import Model.View.PaymentView exposing (PaymentView)
import Model.Translations exposing (getMessage)

import ServerCommunication as SC exposing (serverCommunications)

import Update exposing (..)
import Update.Payment exposing (..)

import View.Icon exposing (renderIcon)
import View.Date exposing (..)

paymentsTable : Model -> PaymentView -> Html
paymentsTable model paymentView =
  div
    [ class "table" ]
    ([ div
        [ class "header" ]
        [ div [ class "cell category" ] [ renderIcon "shopping-cart" ]
        , div [ class "cell cost" ] [ text (getMessage "MoneySymbol" model.translations) ]
        , div [ class "cell user" ] [ renderIcon "user" ]
        , div [ class "cell date" ] [ renderIcon "calendar" ]
        , div [ class "cell" ] []
        ]
    ] ++ (paymentLines model paymentView))

paymentLines : Model -> PaymentView -> List Html
paymentLines model paymentView =
  paymentView.payments
    |> Dict.toList
    |> List.sortBy (\(_, payment) -> Date.toTime payment.creation)
    |> List.reverse
    |> List.map (paymentLine model paymentView)

paymentLine : Model -> PaymentView -> PaymentWithId -> Html
paymentLine model paymentView (id, payment) =
  a
    [ class ("row " ++ (if paymentView.edition == Just id then "edition" else ""))
    , onClick actions.address (UpdatePayment (ToggleEdit id))
    ]
    [ div [ class "cell category" ] [ text payment.name ]
    , div [ class "cell cost" ] [ text ((toString payment.cost) ++ " " ++ (getMessage "MoneySymbol" model.translations)) ]
    , div [ class "cell user" ] [ text payment.userName ]
    , div
        [ class "cell date" ]
        [ span
            [ class "shortDate" ]
            [ text (renderShortDate payment.creation model.translations) ]
        , span
            [ class "longDate" ]
            [ text (renderLongDate payment.creation model.translations) ]
        ]
    , if paymentView.userName == payment.userName
        then
          div
            [ class "cell remove"
            , onClick serverCommunications.address (SC.DeletePayment id)
            ]
            [ renderIcon "times" ]
        else
          div [ class "cell" ] []
    ]