module LoggedIn.Home.AddPayment.Update
  ( update
  , addPaymentError
  ) where

import Maybe
import Json.Decode as Json exposing ((:=))

import LoggedIn.Home.AddPayment.Action as AddPaymentAction
import LoggedIn.Home.AddPayment.Model as AddPaymentModel

import Model.Translations exposing (Translations, getMessage)
import Model.Payment exposing (PaymentFrequency(..))

update : AddPaymentAction.Action -> AddPaymentModel.Model -> AddPaymentModel.Model
update action addPayment =
  case action of

    AddPaymentAction.NoOp ->
      addPayment

    AddPaymentAction.UpdateName name ->
      { addPayment | name = name }

    AddPaymentAction.UpdateCost cost ->
      { addPayment | cost = cost }

    AddPaymentAction.AddError nameError costError ->
      { addPayment
      | nameError = nameError
      , costError = costError
      , waitingServer = False
      }

    AddPaymentAction.ToggleFrequency ->
      { addPayment
      | frequency = if addPayment.frequency == Punctual then Monthly else Punctual
      }

    AddPaymentAction.WaitingServer ->
      { addPayment | waitingServer = True }

addPaymentError : Translations -> String -> Maybe AddPaymentAction.Action
addPaymentError translations jsonErr =
  let decoder =
        Json.object2 (,)
          (Json.maybe <| "name" := Json.string)
          (Json.maybe <| "cost" := Json.string)
  in  case Json.decodeString decoder jsonErr of
        Err _ ->
          Nothing
        Ok (mbNameKey, mbCostKey) ->
          Just <| AddPaymentAction.AddError
            (Maybe.map (flip getMessage translations) mbNameKey)
            (Maybe.map (flip getMessage translations) mbCostKey)