module LoggedIn.Home.AddPayment.View
  ( view
  ) where

import Result exposing (..)
import Signal exposing (Address)

import Html as H exposing (..)
import Html.Attributes exposing (..)
import Html.Events exposing (..)

import LoggedIn.Action as LoggedInAction

import LoggedIn.Home.Action as HomeAction
import LoggedIn.Home.Model as HomeModel

import LoggedIn.Home.AddPayment.Action as AddPaymentAction
import LoggedIn.Home.AddPayment.Model as AddPaymentModel

import Model exposing (Model)
import Model.Payment exposing (PaymentFrequency(..))
import Model.Translations exposing (getMessage)
import Action as Action exposing (..)

import View.Events exposing (onSubmitPrevDefault)
import View.Icon exposing (..)

import Utils.Maybe exposing (isJust)
import Utils.Either exposing (toMaybeError)

view : Address Action -> Model -> HomeModel.Model -> Html
view address model homeModel =
  H.form
    [ let update =
            if homeModel.add.waitingServer
              then
                Action.NoOp
              else
                UpdateLoggedIn << LoggedInAction.HomeAction <| HomeAction.AddPayment homeModel.add.name homeModel.add.cost homeModel.add.frequency
      in  onSubmitPrevDefault address update
    , class "addPayment"
    ]
    [ addPaymentName address homeModel.add
    , addPaymentCost address model homeModel.add
    , paymentFrequency address model homeModel.add
    , button
        [ type' "submit"
        , classList
            [ ("add", True)
            , ("waitingServer", homeModel.add.waitingServer)
            ]
        ]
        [ text (getMessage "Add" model.translations)
        , if homeModel.add.waitingServer then renderSpinIcon else text ""
        ]
    ]

addPaymentName : Address Action -> AddPaymentModel.Model -> Html
addPaymentName address addPayment =
  div
    [ classList
        [ ("name", True)
        , ("error", isJust addPayment.nameError)
        ]
    ]
    [ input
        [ id "nameInput"
        , value addPayment.name
        , on "input" targetValue (Signal.message address << UpdateLoggedIn << LoggedInAction.HomeAction << HomeAction.UpdateAdd << AddPaymentAction.UpdateName)
        , maxlength 20
        ]
        []
    , label
        [ for "nameInput" ]
        [ renderIcon "shopping-cart" ]
    , case addPayment.nameError of
        Just error ->
          div [ class "errorMessage" ] [ text error ]
        Nothing ->
          text ""
    ]

addPaymentCost : Address Action -> Model -> AddPaymentModel.Model -> Html
addPaymentCost address model addPayment =
  div
    [ classList
        [ ("cost", True)
        , ("error", isJust addPayment.costError)
        ]
    ]
    [ input
        [ id "costInput"
        , value addPayment.cost
        , on "input" targetValue (Signal.message address << UpdateLoggedIn << LoggedInAction.HomeAction << HomeAction.UpdateAdd << AddPaymentAction.UpdateCost)
        , maxlength 7
        ]
        []
    , label
        [ for "costInput" ]
        [ text model.conf.currency ]
    , case addPayment.costError of
        Just error ->
          div [ class "errorMessage" ] [ text error ]
        Nothing ->
          text ""
    ]

paymentFrequency : Address Action -> Model -> AddPaymentModel.Model -> Html
paymentFrequency address model addPayment =
  button
    [ type' "button"
    , class "frequency"
    , onClick address (UpdateLoggedIn << LoggedInAction.HomeAction << HomeAction.UpdateAdd <| AddPaymentAction.ToggleFrequency)
    ]
    [ div
        [ classList
            [ ("punctual", True)
            , ("selected", addPayment.frequency == Punctual)
            ]
        ]
        [ text (getMessage "Punctual" model.translations) ]
    , div
        [ classList
            [ ("monthly", True)
            , ("selected", addPayment.frequency == Monthly)
            ]
        ]
        [ text (getMessage "Monthly" model.translations) ]
    ]