module LoggedIn.Update exposing
  ( update
  )

import Dict
import String
import Task

import Http exposing (Error(..))
import Date exposing (Date)
import Platform.Cmd exposing (Cmd)

import Form

import Model exposing (Model)
import Model.Translations exposing (getMessage)
import Model.Payment as Payment exposing (Payment, Frequency(..), deletePayment)

import Server
import LoggedData

import LoggedIn.Msg as LoggedInMsg
import LoggedIn.Model as LoggedInModel

import LoggedIn.Home.Msg as HomeMsg
import LoggedIn.Home.Update as HomeUpdate
import LoggedIn.Home.Model as HomeModel

import LoggedIn.Income.Msg as IncomeMsg
import LoggedIn.Income.Update as IncomeUpdate

import LoggedIn.Income.Model as IncomeModel

import Utils.Tuple as Tuple
import Utils.Cmd exposing ((:>))

update : Model -> LoggedInMsg.Msg -> LoggedInModel.Model -> (LoggedInModel.Model, Cmd LoggedInMsg.Msg)
update model msg loggedIn =
  let loggedData = LoggedData.build model loggedIn
  in  case msg of

        LoggedInMsg.NoOp ->
          ( loggedIn
          , Cmd.none
          )

        LoggedInMsg.HomeMsg homeMsg ->
          case HomeUpdate.update loggedData homeMsg loggedIn.home of
            (home, effects) ->
              ( { loggedIn | home = home }
              , Cmd.map LoggedInMsg.HomeMsg effects
              )

        LoggedInMsg.IncomeMsg incomeMsg ->
          case IncomeUpdate.update loggedData incomeMsg loggedIn.income of
            (income, cmd) ->
              ( { loggedIn | income = income }
              , Cmd.map LoggedInMsg.IncomeMsg cmd
              )

        LoggedInMsg.AddPayment name cost frequency ->
          ( loggedIn
          , Server.addPayment name cost frequency
              |> Task.perform
                   (\err ->
                     case err of
                       BadResponse 400 jsonErr ->
                         LoggedInMsg.NoOp
                       _ ->
                         LoggedInMsg.NoOp
                   )
                   (\paymentId -> LoggedInMsg.ValidateAddPayment paymentId name cost frequency)
          )

        LoggedInMsg.ValidateAddPayment paymentId name cost frequency ->
          update model (LoggedInMsg.HomeMsg <| HomeMsg.SearchMsg (Form.Reset (HomeModel.searchInitial frequency))) loggedIn
            :> update model (LoggedInMsg.HomeMsg <| HomeMsg.SearchMsg Form.Submit)
            :> update model (LoggedInMsg.HomeMsg <| HomeMsg.UpdatePage 1)
            :> (\loggedIn ->
                 let newPayment = Payment paymentId (Date.fromTime model.currentTime) name cost loggedIn.me frequency
                 in  ( { loggedIn | payments = newPayment :: loggedIn.payments }
                     , Cmd.none
                     )
               )

        LoggedInMsg.DeletePayment paymentId ->
          ( loggedIn
          , Server.deletePayment paymentId
              |> Task.perform
                   (always LoggedInMsg.NoOp)
                   (always (LoggedInMsg.ValidateDeletePayment paymentId))
          )

        LoggedInMsg.ValidateDeletePayment paymentId ->
          let payments = deletePayment paymentId loggedIn.payments
              frequency =
                case Form.getOutput loggedIn.home.search of
                  Just data -> data.frequency
                  Nothing -> Punctual
              switchToPunctual =
                (  frequency == Monthly
                && List.isEmpty (Payment.monthly payments)
                )
          in  if switchToPunctual
                then
                  update model (LoggedInMsg.HomeMsg <| HomeMsg.SearchMsg (Form.Reset (HomeModel.searchInitial Punctual))) loggedIn
                    :> update model (LoggedInMsg.HomeMsg <| HomeMsg.SearchMsg Form.Submit)
                    :> (\loggedIn ->
                         ( { loggedIn | payments = payments }
                         , Cmd.none
                         )
                       )
                else
                  ( { loggedIn | payments = payments }
                  , Cmd.none
                  )

        LoggedInMsg.AddIncome time amount ->
          ( loggedIn
          , Server.addIncome time amount
              |> Task.perform
                   (always LoggedInMsg.NoOp)
                   (\incomeId -> (LoggedInMsg.ValidateAddIncome incomeId time amount))
          )

        LoggedInMsg.ValidateAddIncome incomeId time amount ->
          let newIncome = { userId = loggedIn.me, time = time, amount = amount }
              loggedInIncome = loggedIn.income
          in  ( { loggedIn
                | incomes = Dict.insert incomeId newIncome loggedIn.incomes
                , income = { loggedInIncome | addIncome = IncomeModel.initForm }
                }
              , Cmd.none
              )

        LoggedInMsg.DeleteIncome incomeId ->
          ( loggedIn
          , Server.deleteIncome incomeId
              |> Task.perform
                   (always LoggedInMsg.NoOp)
                   (always <| LoggedInMsg.ValidateDeleteIncome incomeId)
          )

        LoggedInMsg.ValidateDeleteIncome incomeId ->
          ( { loggedIn | incomes = Dict.remove incomeId loggedIn.incomes }
          , Cmd.none
          )