module Update
  ( update
  ) where

import Task

import Effects exposing (Effects)

import Server

import Model exposing (Model)
import Model.Translations exposing (getMessage)
import Model.Action exposing (..)
import Model.Action.SignInAction as SignInAction exposing (SignInAction)
import Model.Action.LoggedInAction exposing (LoggedInAction)
import Model.View as V
import Model.View.SignInView exposing (..)
import Model.View.LoggedInView exposing (..)

import Update.LoggedIn exposing (updateLoggedIn)
import Update.SignIn exposing (updateSignIn)

import SimpleHTTP exposing (post)

update : Action -> Model -> (Model, Effects Action)
update action model =
  case action of

    NoOp ->
      (model, Effects.none)

    SignIn assertion ->
      ( applySignIn model (SignInAction.WaitingServer)
      , Server.signIn assertion
          |> flip Task.onError (\_ ->
               Task.succeed (UpdateSignIn (SignInAction.ErrorLogin (getMessage "ErrorSignIn" model.translations)))
             )
          |> Effects.task
      )

    GoLoggedInView users me monthlyPayments payments paymentsCount payers ->
      ( { model | view = V.LoggedInView (initLoggedInView users me monthlyPayments payments paymentsCount payers) }
      , Effects.none
      )

    UpdateTime time ->
      ({ model | currentTime = time }, Effects.none)

    GoSignInView ->
      ({ model | view = V.SignInView initSignInView }, Effects.none)

    UpdateSignIn signInAction ->
      (applySignIn model signInAction, Effects.none)

    UpdateLoggedIn loggedInAction ->
      applyLoggedIn model loggedInAction

    SignOut ->
      ( model
      , Server.signOut
          |> flip Task.onError (always <| Task.succeed NoOp)
          |> Effects.task
      )

applySignIn : Model -> SignInAction -> Model
applySignIn model signInAction =
  case model.view of
    V.SignInView signInView ->
      { model | view = V.SignInView (updateSignIn signInAction signInView) }
    _ ->
      model

applyLoggedIn : Model -> LoggedInAction -> (Model, Effects Action)
applyLoggedIn model loggedInAction =
  case model.view of
    V.LoggedInView loggedInView ->
      let (loggedInView, effects) = updateLoggedIn model loggedInAction loggedInView
      in  ( { model | view = V.LoggedInView loggedInView }
          , Effects.map UpdateLoggedIn effects
          )
    _ ->
      (model, Effects.none)