module Update.LoggedIn
  ( updateLoggedIn
  ) where

import Date
import Dict

import Model exposing (Model)
import Model.User exposing (UserId)
import Model.Payment exposing (..)
import Model.Action.LoggedInAction exposing (..)
import Model.Action.AccountAction exposing (..)
import Model.Action.MonthlyAction as Monthly
import Model.View.LoggedInView exposing (..)
import Model.View.LoggedIn.AddPayment exposing (..)

import Update.LoggedIn.AddPayment exposing (updateAddPayment)
import Update.LoggedIn.Monthly exposing (updateMonthly)
import Update.LoggedIn.Account exposing (updateAccount)

updateLoggedIn : Model -> LoggedInAction -> LoggedInView -> LoggedInView
updateLoggedIn model action loggedInView =
  case action of
    UpdateAdd addPaymentAction ->
      { loggedInView | add = updateAddPayment addPaymentAction loggedInView.add }
    UpdatePayments payments ->
      { loggedInView | payments = payments }
    AddPayment paymentId name cost frequency ->
      let newPayment = Payment paymentId (Date.fromTime model.currentTime) name cost loggedInView.account.me
          newAdd = initAddPayment frequency
      in  if frequency == Punctual
             then
               { loggedInView
               | currentPage = 1
               , add = newAdd
               , account = updateAccount (UpdatePayer loggedInView.account.me model.currentTime cost) loggedInView.account
               , payments = newPayment :: loggedInView.payments
               , paymentsCount = loggedInView.paymentsCount + 1
               }
             else
               { loggedInView
               | add = newAdd
               , monthly = updateMonthly (Monthly.AddPayment newPayment) loggedInView.monthly
               }
    ToggleEdit id ->
      { loggedInView | paymentEdition = if loggedInView.paymentEdition == Just id then Nothing else Just id }
    DeletePayment payment frequency ->
      case frequency of
        Monthly ->
          { loggedInView
          | monthly = updateMonthly (Monthly.DeletePayment payment) loggedInView.monthly
          }
        Punctual ->
          { loggedInView
          | account = updateAccount (UpdatePayer payment.userId (Date.toTime payment.creation) -payment.cost) loggedInView.account
          , payments = deletePayment payment.id loggedInView.payments
          , paymentsCount = loggedInView.paymentsCount - 1
          }
    UpdatePage page ->
      { loggedInView
      | currentPage = page
      }
    UpdateMonthly monthlyAction ->
      { loggedInView | monthly = updateMonthly monthlyAction loggedInView.monthly }
    UpdateAccount accountAction ->
      { loggedInView | account = updateAccount accountAction loggedInView.account }