{-# LANGUAGE OverloadedStrings #-}

import Web.Scotty

import Network.Wai.Middleware.Static

import Control.Concurrent (forkIO)

import MonthlyPaymentJob (monthlyPaymentJobListener)

import Data.Text (Text)
import qualified Data.Text.IO as T

import Controller.Index
import Controller.SignIn
import Controller.Payment
import Controller.User
import Controller.Payer

import Model.Database (runMigrations)
import Model.Frequency

import qualified Conf

main :: IO ()
main = do
  runMigrations
  _ <- forkIO monthlyPaymentJobListener
  confOrError <- Conf.getConf "application.conf"
  case confOrError of
    Left errorMessage ->
      T.putStrLn errorMessage
    Right conf -> do
      scotty (Conf.port conf) $ do
        middleware $
          staticPolicy (noDots >-> addBase "public")

        get  "/" $
          ( do
              signInToken <- param "signInToken" :: ActionM Text
              successOrError <- validateSignIn conf signInToken
              case successOrError of
                Left errorKey ->
                  (getIndex conf (Just errorKey))
                Right _ ->
                  (getIndex conf Nothing)
          ) `rescue` (\_ -> getIndex conf Nothing)

        post "/signOut"      signOut

        -- SignIn

        post "/signIn" $ do
          email <- param "email" :: ActionM Text
          signIn conf email

        -- Users

        get  "/users"  getUsers
        get  "/whoAmI" whoAmI
        get  "/income" getIncome
        post "/income" $ do
          amount <- param "amount" :: ActionM Int
          setIncome amount

        -- Payments

        get "/payments" getPayments

        get "/monthlyPayments" getMonthlyPayments

        post "/payment/add" $ do
          name <- param "name" :: ActionM Text
          cost <- param "cost" :: ActionM Text
          frequency <- param "frequency" :: ActionM Frequency
          createPayment name cost frequency

        post "/payment/delete" $ do
          paymentId <- param "id" :: ActionM Text
          deletePayment paymentId

        get "/payments/count" getPaymentsCount

        -- Payers

        get "/payers" getPayers