{-# LANGUAGE OverloadedStrings #-}

module Design.Global
  ( compactDesign
  ) where

import qualified Data.Text.Lazy as T
import Data.Monoid ((<>))

import Clay

import qualified Design.Color as Color
import qualified Design.Media as Media
import Design.Header (headerCss)
import Design.Resume (resumeCss)
import Design.Projects (projectsCss)
import Design.NotFound (notFoundCss)

compactDesign :: T.Text
compactDesign = renderWith compact [] $ global

global :: Css
global =
  body ? do
    color Color.black
    marginBottom (px 40)
    Media.mobile $ fontSize (px 16)
    Media.tabletDesktop $ fontSize (px 18)

    h1 ? do
      fontFamily [] [monospace]
      fontWeight bold
      color Color.red

      Media.mobile $ do
        lineHeight (px 30)
        fontSize (px 22)
        marginBottom (px 20)
        marginTop (px 35)

      Media.tablet $ do
        lineHeight (px 40)
        fontSize (px 27)
        marginBottom (px 35)
        marginTop (px 45)

      Media.desktop $ do
        lineHeight (px 50)
        fontSize (px 30)
        marginBottom (px 40)
        marginTop (px 55)

    a ? do
      textDecoration none
      color Color.link
      transition "color" (sec 0.3) easeOut (sec 0)
      focus & outline solid (px 0) Color.white

    (a # hover) <> (a # focus) ? do
      textDecoration underline
      color Color.blue

    headerCss
    resumeCss
    projectsCss
    notFoundCss